Tag Archives: Windows

Programming Windows

VBScript: List all installed applications

Just a simple inventory script. This script does NOT query the WMI Installed_Product table, which an be quite time and CPU consuming. Instead, my script queries the Uninstall-Registry key to generate the list of installed apps which makes it lot faster:

' #####################################################################
' ##
' ## (C) 2010 Michael Miklis (michaelmiklis.de)
' ##
' ## 
' ## Filename:      GetInstalledApplications.vbs
' ##
' ## Version:	    1.0
' ##
' ## Release:	    Final 
' ##
' ## Requirements:  -none-
' ## 
' ## Description:   List installed applications based on uninstall key
' ##
' ## This script is provided 'AS-IS'.  The author does not provide 
' ## any guarantee or warranty, stated or implied.  Use at your own 
' ## risk. You are free to reproduce, copy & modify the code, but 
' ## please give the author credit. 
' ##
' ####################################################################
Option Explicit


wscript.echo GetInstalledApplications


'______________________FUNCTIONS & SUB ROUTINES_______________________

Function GetInstalledApplications
	'// <summary> 
	'// List installed applications
	'// </summary>
	'// <param name="strComputername">Computername</param>
 
	Const HKLM = &H80000002		'HKEY_LOCAL_MACHINE

	Dim objREG			'Registry Object
	Dim strBaseKey			'Uninstall Key
	Dim intRet			'Return Code
	Dim arSubKeys			'Reg-Key Array
	Dim strKey			'Reg-Key Element
	Dim strValue			'Reg-Value

	Set objREG = GetObject("winmgmts:{impersonationLevel=impersonate}!./root/default:StdRegProv")
	strBaseKey = "SOFTWAREMicrosoftWindowsCurrentVersionUninstall"

	intRet = objREG.EnumKey(HKLM, strBaseKey, arSubKeys)

	For Each strKey In arSubKeys
		intRet = objREG.GetStringValue(HKLM, strBaseKey & strKey, "DisplayName", strValue)

		If intRet <> 0 Then
			objREG.GetStringValue HKLM, strBaseKey & strKey, "QuietDisplayName", strValue
		End If

		If strValue <> "" Then
			GetInstalledApplications = GetInstalledApplications & strValue & vbCrLf
		End If
	Next
End Function
Read More
Programming Windows

VBScript: List all files in a directory recursively

This is definitely my most used VBScript function ever. Just specify a directory a you’ll receive a complete directory listing recursively.

' #####################################################################
' ##
' ## (C) 2005 Michael Miklis (michaelmiklis.de)
' ##
' ## 
' ## Filename:      ListFilesRecursive.vbs
' ##
' ## Version:	    1.0
' ##
' ## Release:	    Final 
' ##
' ## Requirements:  -none-
' ## 
' ## Description:   Creates a List of files and folders
' ##
' ## This script is provided 'AS-IS'.  The author does not provide 
' ## any guarantee or warranty, stated or implied.  Use at your own 
' ## risk. You are free to reproduce, copy & modify the code, but 
' ## please give the author credit. 
' ##
' ####################################################################
Option Explicit

Dim objFS

Set objFS = CreateObject ("Scripting.FileSystemObject")

wscript.echo CreateFileList(objFS.GetFolder("C:\Users\michael\desktop"), True)

Set objFS = Nothing

'______________________FUNCTIONS & SUB ROUTINES_______________________

Function CreateFileList(objFolder, bRecursive)
	'// <summary> 
	'// 	Creates a List containing all Files
	'// </summary> 
	'// <param name="objFolder">Root-Folder for searching</param> 	
	'// <param name="bRecursive">Search recursive</param>
	Dim objFile, objSubFolder

        For each objFile in objFolder.Files
        	CreateFileList = CreateFileList & objFile.Path & vbCr
	Next

	If bRecursive = true then
		For each objSubFolder in objFolder.Subfolders
			CreateFileList = CreateFileList & CreateFileList(objSubFolder, true)
	        Next
	End If
End Function
Read More
Programming Windows

VBScript: Ping Function

Just another useful function using the Windows Management Infractstructre (WMI) for doing a ICMP Ping. I’ve used this function on all my network related scripts to verify a host is available on the network.

' #####################################################################
' ##
' ## (C) 2009 Michael Miklis (michaelmiklis.de)
' ##
' ## 
' ## Filename:      Ping.vbs
' ##
' ## Version:	    1.0
' ##
' ## Release:	    Final 
' ##
' ## Requirements:  -none-
' ## 
' ## Description:   Pings a network host or device
' ##
' ## This script is provided 'AS-IS'.  The author does not provide 
' ## any guarantee or warranty, stated or implied.  Use at your own 
' ## risk. You are free to reproduce, copy & modify the code, but 
' ## please give the author credit. 
' ##
' ####################################################################
Option Explicit

If Ping("www.google.com") = true then
	wscript.echo "alive"
End If

'______________________FUNCTIONS & SUB ROUTINES_______________________

Function Ping(strHost)
	'// <summary> 
	'// Well Known Ping command
	'// </summary>
	'// <param name="strHost">Name or IP-Address</param>


	Dim objPing			'WMI Ping Object
	Dim objStatus			'PingStatus Object

	Ping = false

	Set objPing = GetObject("winmgmts:{impersonationLevel=impersonate}")._
	ExecQuery("SELECT * FROM Win32_PingStatus where address = '" & strHost & "'")

	'// Query Win32_PingStatus.StatusCode -> 0 = reachable
	For each objStatus in objPing
		If objStatus.StatusCode = 0 then
			Ping = true
			Exit Function
		End If
	Next
End Function
Read More
XenApp XenDesktop

Change Clientdrive Name and Icon (Example: Mein IGEL)

Today I created a script to make it easier for IGEL Linux ThinClient users to find their client USB drives. On IGEL Linux ThinClients, all USB client devices are mapped under the virtual client drive A: (clienta$). Unfortunately, it isn’t that easy to recognize for the regular users in the Windows Explorer if they are connected to a XenApp or XenDesktop machine.
Therefore I decided to make it a lot easier for the User – and here we go – that’s how it looks now:



So what do we need to do to get there? I wrote a batch script that does the Job for you – this script needs to be run everytime a user logs on to the XenApp or XenDesktop session. This can be done with the regular login script or with group policy preferences – for my first implementation I did it with GPP and used item level targeting for specifying an Active Directory Group.

Here’s the Script:

MeinIGEL.cmd

You need to customize the Script regarding the path to the IGEL icon file to fit your environment. For Copyright reasons, I can’t offer an IGEL icon file for download – you have to create your own.

Read More
Windows

Clear all Windows Evenlogs

To clear all Eventlogs in Windows just use this simple powershell command:

wevtutil el | ForEach-Object { wevtutil cl "$_" }

Read More
Programming Windows

Changing a Template or Templatepath in Word Documents via Script

During a fileserver migration I encountered a problem – users started to report that it takes unusually long to open Microsoft Word Documents. I did some investigations on this and found out that Word is saving the FQDN of the template path (*.dot) file. You can see this if you open a document in the Word splash screen.

You can manually change the template path within the document options in word – but what if you have thousands of files and you even don’t know which one are affected?

Here’s the answer: I just wrote a little script that will modify all documents within the given path.

You just need to modify the lines 45, 46, 47 to fit your environment

' #####################################################################
' ##
' ## (C) 2012 Michael Miklis (michaelmiklis.de)
' ##
' ## 
' ## Filename:      ChangeWordDocumentTemplate.vbs
' ##
' ## Version:	    1.0
' ##
' ## Release:	    Final 
' ##
' ## Requirements:  -none-
' ## 
' ## Description:   Changes the template in doc files
' ##
' ## This script is provided 'AS-IS'.  The author does not provide 
' ## any guarantee or warranty, stated or implied.  Use at your own 
' ## risk. You are free to reproduce, copy & modify the code, but 
' ## please give the author credit. 
' ##
' ####################################################################
Option Explicit

Dim strFilePath
Dim strPath
Dim intCounter
Dim strFileName
Dim OldServer
Dim NewServer
Dim objDoc
Dim objTemplate
Dim dlgTemplate
Dim objWord
Dim strFileArr
Dim objFs
Dim i

Const wdDialogToolsTemplates = 87

Set objFS = CreateObject("Scripting.Filesystemobject")

Set objWord = CreateObject("Word.Application")
objWord.Visible = false

strFilePath = "C:\Testfiles"
OldServer = "\\server_old\share\folder1\folder1.1" 
NewServer = "\\server_new\share\folder1\folder1.1"


If Right(strFilePath, 1) = "\" Then strFilePath = Left(strFilePath, Len(strFilePath) - 1)

strFileArr = Split(CreateFileList(objFS.GetFolder(strFilePath),true), vbCr)

For i=0 to UBound(strFileArr)
	If NOT strFileArr(i) = "" then
		strFileName = strFileArr(i)

		wscript.echo "--------------------------------------------------"
		wscript.echo "Processing File: " & strFilename

		Set objDoc = objWord.Documents.Open(strFileName)    
		Set objTemplate = objDoc.AttachedTemplate    
		Set dlgTemplate = objWord.Dialogs(wdDialogToolsTemplates)    
		strPath = dlgTemplate.Template

		wscript.echo "Old Template Name: " & strPath

		'// Only process templates based on old server
		If LCase(Left(strPath, Len(OldServer))) = LCase(OldServer) Then
			wscript.echo "Template needs to be changed..."    
			objDoc.AttachedTemplate = NewServer & Mid(strPath, Len(OldServer) + 1)
			wscript.echo "New Template Name: " & NewServer & Mid(strPath, Len(OldServer) + 1)
		End If    

		objDoc.Save                  
		objDoc.Close

		wscript.echo "--------------------------------------------------"
		wscript.echo ""
	End If
Next 

Set objDoc = Nothing
Set objTemplate = Nothing
Set dlgTemplate = Nothing  

'// Close Word
objWord.Quit (False)

'______________________FUNCTIONS & SUB ROUTINES_______________________

Function CreateFileList(objFolder, bRecursive)
	'// <summary> 
	'// 	Creates a List containing all Files
	'// </summary> 
	'// <param name="objFolder">Root-Folder for searching</param> 	
	'// <param name="bRecursive">Search recursive</param>
	Dim objFile, objSubFolder


        For each objFile in objFolder.Files
		If Right(lcase(objFile),4) = ".doc" OR Right(lcase(objFile),5) = ".docx" AND NOT Left(objFile.Name,1) = "~" then
	        	CreateFileList = CreateFileList & objFile.Path & vbCr
		End If
	Next

	If bRecursive = true then
		For each objSubFolder in objFolder.Subfolders
			CreateFileList = CreateFileList & CreateFileList(objSubFolder, true)
	        Next
	End If
End Function

Read More
XenApp

Citrix XenApp XML Service shared with IIS not working after sysprep

A coworker of mine had problems regarding Citrix XenApp XML Service shared with IIS7 on a syspreped Windows Server 2008 R2. After a little research and investigations I found a Citrix support article regarding this problem:

http://support.citrix.com/article/CTX131137

Here’s also a short guide how to configure IIS portsharing with Citrix XML Service:

http://support.citrix.com/article/CTX125107

Read More
Windows XenDesktop

XenDesktop: Change mouse scheme to speedup user experience

On many XenDesktop installations with Windows 7 VMs I ran into a problem regarding the mouse performance. The mouse seems to be quite slow and slaggy if you’ve loaded the Win7 Aero theme.
This is caused by the mouse scheme “Windows Aero”. You need to disable this either in the default profile or via group policy preferences during login:

HKEY_CURRENT_USERControl PanelCursorsScheme Source
Scheme Source=dword:00000000

I assume that the same setting is gonna work on Windows 8 based VDI machines, but I don’t have tested this so far.

Read More
1 2